/**
 * RandText as2.0 libray
 * @author youji maekawa
 * @version 1.0
 */
 class as.randtext.RandText extends MovieClip{
	private var targetMc:MovieClip;
	private var targetFld:TextField;
	private var targetText:String;
	private var sourceTxt:String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890";
	private var dummyMc:MovieClip;
	//
	function RandText(_mc, _fld) {
		targetMc = _mc;
		targetFld = _fld;
		targetText = targetFld.text;
		init();
	}
	private function init(){
		targetFld.text = "";
	}
	function set randomTxt(_str:String){
		sourceTxt = _str;
	}
	function startRandom() {
		init();
		//
		if(dummyMc != undefined){
			removeMovieClip(dummyMc);
			dummyMc = undefined;
		}
		var depth = targetMc.getNextHighestDepth();
		dummyMc = targetMc.createEmptyMovieClip("dummy"+depth, depth);
		//
		var sliceCnt = 0
		var owner = this;
		dummyMc.onEnterFrame = function() {
			++sliceCnt;
			var randomTxt = "";
			for (var i = 0; i<owner.targetText.length; ++i) {
				if (sliceCnt-10<i) {
					randomTxt = randomTxt+owner.sourceTxt.charAt(Math.floor(Math.random()*owner.sourceTxt.length));
					continue;
				}
				randomTxt = randomTxt+owner.targetText.charAt(i);
			}
			owner.targetFld.text = randomTxt;
			if (randomTxt == owner.targetText) {
				delete this.onEnterFrame;
			}
		};
	}
}